Plantilla de entradas y salidas de inventario en Google Sheets

Archivo de Gestion de Inventarios en Google Sheets
— by

En este artículo vamos a crear un archivo o plantilla de gestión de entradas y salidas de inventario en Google Sheets desde cero. Un sistema de control de almacén donde podremos registrar las salidas y entradas de productos y ver cuanto inventario tenemos de cada referencia.

En que consiste el Archivo de Gestión de Inventarios

Que es Gestión de Inventarios

El objetivo principal de la gestión de inventarios es saber en cualquier momento cuantas unidades nos quedan de algún producto específico.

Adicionalmente, puede ser útil para ayudarnos a responder algunas otras preguntas como

  • ¿Cuánto dinero tengo acumulado en inventarios?
  • ¿Cuáles son los productos con más inventario?
  • ¿Cuáles son los productos con más dinero en inventario (Que no son necesariamente los que tienen más unidades)?
  • ¿Cuándo tengo que pedir nuevamente de alguna unidad?
  • ¿Cuáles productos en inventario están por vencerse?

¿Qué necesitamos?

Ya vimos que un archivo de gestión de inventarios nos puede servir para muchas cosas, pero por ahora nos vamos a enfocar en la pregunta principal ¿Cuántas unidades tengo de cada ítem al día de hoy?

Para poder responder esta pregunta necesitamos lo siguiente:

  • Tener un registro de lo que entra, llámese compras, egresos, entradas, etc.
  • Tener un registro de lo que sale: llámese egresos, las salidas o las ventas (lo mismo, pero con distintas palabras).

Adicionalmente, para asegurarnos de que sumemos «peras con peras», podemos tener un registro de productos, junto con unas referencias, para que cuando registremos entradas y/o salidas, estemos hablando de los mismos productos.

Aquí puedes obtener una copia de la plantilla que usamos en este paso a paso, lo que puede ayudar a entender mejor todo el tutorial.

Si prefieres, te dejo todo un curso entero de Gestión de Inventarios en mi academia de automatización de Google Sheets

Creando la plantilla de entradas y salidas

Hoja de Ingreso de Productos

Vamos a empezar entonces por nuestros productos: «la base de toda nuestra base».

Lo mínimo que necesita una base de productos es una referencia y un nombre.

Podríamos trabajar solo con nombres, pero la buena práctica de contar con una referencia nos obliga a tener algún código irrepetible. El problema con los nombres es que una mayúscula, un espacio, una tilde, pueden desajustarnos nuestra base, mientras que una referencia es más sólida y más confiable. Además que los nombres podrían llegar a repetirse.

La referencia puede seguir el patrón que ustedes quieran. Mis recomendaciones son:

  • Que no tenga espacios
  • Que no sea tan larga
  • Que tenga letras y números
  • Que las letras signifiquen algo
  • Que los números sigan un orden secuencial
  • Que dejen espacio para la cantidad de productos que podría llegar a tener en una categoría especifica
  • Que siempre tengan el mismo largo

Si yo vendo pizzas por ejemplo, una referencia, podría ser

PIZZ001

Rápidamente podemos ver que el producto se trata de una pizza, y tengo 999 espacios para tener más pizzas, las bebidas podrían ser BEBI, y los postres POST. Es solo un ejemplo.

También podría ir un paso más allá, siguiendo el ejemplo de las pizzas y poner una segunda serie de letras, como

PIZZ-ESPE-001

PIZZ-TRAD-001

PIZZ-VEGE-001

En fin, puede ser lo que ustedes quieran, pero traten de ser consistentes, y de pensar a futuro para que no les toque estar cambiando las referencias en el camino.

También podríamos generar las referencias de manera automática, pero eso lo veremos en otra ocasión.

Entonces, ahora si, manos a la obra.

Para crear nuestra base de productos, vamos a hacer lo siguiente:

1. Vamos a crear una hoja de cálculo nueva en Sheets.

  1. Asegúrense de tener una cuenta de Google (Gmail). Si no, la pueden crear aquí.
  2. Si tienen varias cuentas, asegúrense de estar activos en la cuenta donde quieren crear el control de inventarios
  3. El archivo lo pueden crear de varias maneras:
    1. Desde su drive, den clic derecho y escojan «Hoja de Cálculo de Google» > «Nueva Hoja de Cálculo»
    2. Desde otro archivo de Sheets, en «Archivo» > «Nuevo» > «Hoja de cálculo»
    3. En su navegador ingresen sheets.new. O sigan este link.

2. Vamos a renombrar la pestaña «Hoja 1» como «Productos».

3. Vamos a crear los encabezados «REF» y «PRODUCTOS».

Si tienen más atributos del producto que quieran incluir, aquí es donde se haría. Entre las características o variables que se podrían incluir están:

  • Color o colores
  • Tamaño o tamaños
  • Precio sugerido
  • Proveedor
  • Cantidad por caja
  • Categoría
  • Descripción
  • Comentarios

4. Empezamos a crear nuestros productos.

Así quedaría un ejemplo:

Hoja de Ingreso de Entradas

Ya teniendo nuestra base de productos, la podemos usar para que sea mucho más fácil registrar las entradas y salidas.

1. Vamos a crear una nueva pestaña y llamarla «Entradas»

2. Vamos a crear los campos (o encabezados) esenciales, los cuales van a ser:

  • Referencia
  • Nombre
  • Cantidad
  • Fecha

Normalmente la referencia va de primero, pero una opción válida es poner primero el nombre, y que nuestra búsqueda de productos para agregar sea por nombre y no por referencia

¿Por qué primero nombre? Porque es mucho más fácil agregar, recordar o buscar un producto por nombre que por referencia. Recuerden que la referencia esta hecha para ordenar nuestros productos, no para hacernos la vida más difícil

Pero en este caso lo vamos a hacer de la manera más sencilla y después lo mejoraremos.

Para escoger la referencia vamos a usar la validación por medio de una lista. Tranquilos que suena más complicado de lo que en realidad es:

3. Vamos a escoger toda la columna 1 (la de la referencia), sin el encabezado. (Tip: ubíquense en A2 y presionen Ctrl + Shift + Abajo)

4. Damos clic derecho y en el nuevo menú escogemos Validación de Datos

  • En «Criterios», dejamos la opción por defecto «Lista a partir de un intervalo»
  • Nos paramos en el campo del lado con una cuadrícula, y esto nos permite escoger nuestro rango para la lista.
  • Vamos a la pestaña «Productos» y escogemos toda la columna de referencias, desde la fila 2.
  • Por último escogemos la opción «Rechazar la entrada»

Si quieren profundizar en el tema de listas desplegables aquí les dejo un artículo.

Ya quedaron las referencias. Prueben que puedan escoger en la primera columna, una de sus referencias.

Ahora lo que queremos es que cuando escojamos una referencia, el programa nos traiga automáticamente el nombre del producto, para eso nos vamos a apoyar en la función BUSCARV.

Nos ubicamos en la celda B2, y escribimos la siguiente función

=BUSCARV(A2;Productos!$A:$B;2;0)

Si quieren profundizar en el tema de BUSCARV aquí les dejo un artículo.

Adicionalmente, para poder arrastrarla a todas las filas, la vamos a encerrar dentro de un SI.ERROR, entonces reemplacen la anterior por la siguiente:

=SI.ERROR(BUSCARV(A2;Productos!A:B;2;0);»»)

Ahora la arrastramos a toda la columna, así:

  • Copiamos B2 (Ctrl + C)
  • Vamos hasta la última fila (Ctrl + Shift + Abajo)
  • Pegamos (Ctrl + V)

Por último nos aseguramos que haya quedado bien, ubicándonos en cualquier celda de la columna B, y en la barra de fórmulas nos tiene que aparecer nuestra misma formula pero con la fila actual

Las unidades y el costo por unidad ya cada uno lo pondrá manualmente en cada compra o ingreso.

Un último detalle: para asegurarnos que siempre que introduzcamos la fecha del ingreso, el formato sea el adecuado, vamos a poner un pequeño calendario para escoger la fecha.

Para esto, escogemos la columna de la fecha, desde la fila 2 hasta la última fila (ya sabemos como), otra vez clic derecho y escogemos «Validación de Datos», pero esta vez en criterio, vamos a escoger fecha, y dejamos «Es una fecha valida». Damos clic en «Rechazar entrada» y «Aceptar»

Entonces intenten ahora dar doble click sobre cualquier celda debajo del encabezado «Fecha»

Y ya acabamos con las entradas.

Hoja de Ingreso de Salidas

La pestaña de salidas es prácticamente una copia de la pestaña Entradas, entonces para no desgastarnos, dupliquemos la pestaña «Entradas»

Damos clic derecho en la pestaña Entradas y escogemos Duplicar

Les va a crear una pestaña que se llama «Copia de Entradas». Le cambiamos el nombre (con doble clic sobre la pestaña) a Salidas.

Lo único que tenemos que cambiar es COSTO por PRECIO, y ya está!

Hoja de consulta de Inventarios

Ahora si a lo que vinimos.

Ya tenemos nuestras entradas y salidas, ahora solo necesitamos hacer una especie de hoja de resumen donde sumemos las entradas y restemos las salidas por cada producto.

Vamos a crear la pestaña con nombre «Inventarios»

De nuevo, vamos a crear los campos esenciales, y ya ustedes verán lo que quieran agregarle adicional. En este campo las columnas esenciales serían:

  • Referencia
  • Nombre producto
  • Entradas
  • Salidas
  • Inventario

Entonces vamos a crear esas columnas

Aquí no vamos a escoger nada, todo lo vamos a traer mediante fórmulas.

Lo primero que vamos a traer son los productos, pero no todos los productos, sino los productos que tengan alguna entrada, porque si no tienen entrada, pues podemos asumir que no tienen inventario y no hay necesidad de traerlos.

Para esto nos vamos a apoyar en la función UNIQUE que nos va a traer todos los registros de referencias de producto de la pestaña entrada pero sin repetir ninguno.

=UNIQUE(Entradas!A2:A)

Esta función a diferencia de todas las que hemos mencionado, no hay que arrastrarla, simplemente se ingresa en la segunda fila.

Para nombre ahí si podemos usar el BUSCARV de siempre. Pueden ir a copiarlo de la segunda fila de Entradas o Salidas. Esta si la tienen que arrastrar hasta la última fila usando el SI.ERROR como hicimos antes.

Para Entradas y Salidas vamos a usar una fórmula similar: SUMAR.SI

Lo que vamos a hacer es sumar todas las entradas de esa referencia especifica. Para eso usamos la siguiente función en la primera celda debajo del encabezado ENTRADAS:

=SUMAR.SI(Entradas!A:A;A2;Entradas!C:C)

Si arrastramos esta fórmula, nos va a dar 0 cuando no haya producto en una fila. Para evitar esto, vamos a encapsular nuestro sumar.si en otro si

=SI(SUMAR.SI(Entradas!A:A;A2;Entradas!C:C)=0;»»;SUMAR.SI(Entradas!A:A;A2;Entradas!C:C))

Ahora si la arrastramos

Para las salidas es exactamente la misma formula, pero con la pestaña Salidas. Simplemente asegúrense que el segundo argumento corresponde a la columna donde están las unidades, en nuestro caso C.

=SI(SUMAR.SI(Salidas!A:A;A2;Salidas!C:C)=0;»»;SUMAR.SI(Salidas!A:A;A2;Salidas!C:C))

Lo único que nos queda es restar las salidas de las entradas.

Entonces nuestra columna de inventarios quedaría:

Simplemente sería

=C2-D2

Si de nuevo queremos que quede un poco más «limpia», podemos encerrarla en un si, para que solo nos haga el cálculo si hay algún valor en la referencia

Quedaría así:

=SI(ESBLANCO(A2);»»;C2-D2)

Y ahora si arrastramos la fórmula.

Y listo!

Resumen de las pestañas iniciales

Paremos un momento y resumamos lo que ya hemos hecho:

Estas son las pestañas y campos que ya hemos creado y formulado:

  • Pestaña de productos
    • Referencia
    • Nombre
  • Pestaña de Entradas
    • Referencia
    • Fecha de Entrada
    • Cantidad
  • Pestaña de Salidas
    • Referencia
    • Fecha de Salida
    • Cantidad
  • Pestaña de Inventarios
    • Referencias con alguna entrada
    • Entradas totales de cada referencia
    • Salidas totales de cada referencia
    • Inventario restante de cada referencia

Puedes ver este tutorial, con muchas más opciones en el curso entero de Gestión de Inventarios en mi academia de automatización de Google Sheets

Ahora sigamos:

Pestaña de Ajustes

A veces algo le puede pasar a nuestro inventario: se puede perder, se lo pueden robar, se puede dañar, se puede vencer, puedo regalar algunas unidades.

Normalmente deberíamos revisar nuestro inventario periódicamente y compararlo con nuestro listado. Así comparamos el inventario teórico con el real y podemos ajustar nuestra base de inventarios para que refleje lo que realmente hay.

Aunque teóricamente esto lo podríamos incluir en las pestañas de entradas o de salidas, sabiendo que lo que esté en entradas suma y lo que esté en salidas resta, pero personalmente creo que se debería tener por aparte, por que las entradas y salidas deberían estar relacionadas con la operación natural del negocio, es decir con las ventas (salidas) y las compras (entradas)

Esta pestaña de ajustes se puede hacer de varias maneras: Puede ser muy similar al de salidas, ya que la mayoría de ajuste siempre van a restar, pero yo prefiero hacerlo similar al de entradas y que reste, para que sea más lógico ver un «-1», y saber que le resto 1.

Como todo lo que estamos haciendo, siempre depende de nuestras necesidades específicas (y esa es la gran ventaja de hacerlo en hojas de cálculo y no depender de un software externo), pero estos serian para mí los campos necesarios para la hoja de Ajustes:

  • REF
  • NOMBRE
  • UNIDADES REALES
  • AJUSTE O DIFERENCIA
  • FECHA DEL AJUSTE
  • TIPO DE AJUSTE O RAZON DEL AJUSTE
  • También podríamos incluir un campo «UNIDADES ESPERADAS» si lo desean

La referencia va a ser una lista desplegable como ya la hicimos para las entradas y salidas

Así mismo el nombre lo traemos con el BUSCARV, tal como lo hicimos en esa primera parte.

En Unidades, podemos poner una nota, donde expliquemos que es opcional e informativo para saber cuantas unidades habían de esa referencia en esa fecha. Esto aplica más que todo cuando hablamos de un ajuste periódico.

En Diferencia pondríamos en cuanto se desajustó el inventario. Negativo si falta, Positivo si sobra. También podemos poner una nota, sobre todo si este archivo lo van a usar más personas.

En fecha ponemos una validación de fecha como ya hicimos en Entradas y Salidas.

Por último, la razón del ajuste va a ser un listado desplegable con las siguientes opciones:

  • Ajuste mensual
  • Robo
  • Perdida
  • Regalo
  • Daño
  • Vencimiento
  • Devolución

Hay varias maneras de hacer este listado. Para estas listas, yo siempre creo una pestaña adicional que se llame «listas», donde voy a incluir todas las listas o ayudas que vaya a necesitar para mi archivo:

Quedaría así:

Ahora incluimos este listado como una validación de datos, así:

  • Vamos a escoger toda la columna 1 (la de la referencia), sin el encabezado. (Tip: párense en A2 y presionen Ctrl + Shift + Abajo)
  • Damos clic derecho y en el nuevo menú escogemos Validación de Datos.
  • En «Criterios», dejamos la opción por defecto «Lista a partir de un intervalo»
  • Nos paramos en el campo del lado con una cuadrícula, y esto nos permite escoger nuestro rango para la lista.
  • Vamos a la pestaña «Listas» y escogemos nuestro listado de tipos de ajuste, dejando unas 5 o 10 celdas abajo, por si incluyó más razones más adelante.
  • Damos aceptar
  • Por último escogemos la casilla «Rechazar la entrada»
  • Clic en Aceptar

Por último necesitamos incluir estos ajustes en nuestra pestaña de Inventarios.

Para esto vamos a la pestaña «Inventarios, y al lado derecho de salidas creamos una nueva columna «Ajustes» e incluimos una fórmula igual a la de salidas pero, obviamente con los datos de Ajustes. En nuestro caso sería:

=SI(SUMAR.SI(Ajustes!A:A;A2;Ajustes!D:D)=0;»»;SUMAR.SI(Ajustes!A:A;A2;Ajustes!D:D))

Por último nos aseguramos que en la columna inventario, estemos sumando los ajustes

=SI(C2=»»;»»;C2-D2+E2)

Quedaría así nuestra pestaña de inventarios, ya teniendo en cuenta los ajustes.

Suscríbete para acceder al curso «Descubriendo el poder de Google Sheets» y empezar tu camino a la maestría de Sheets, Forms y Apps Script

Funcionalidades más avanzadas para nuestro inventario

Incluir Costos

Ahora vamos a incluir los costos de nuestros inventarios.

Hay muchas metodologías para costear inventarios pero no nos vamos a enredar, vamos a usar la más sencilla: el promedio del costo histórico de cada referencia.

Esto quiere decir que tenemos que incluir en la pestaña «Entradas» una columna de costo, para que cada vez que incluyamos una nueva entrada, ingresemos el costo de los ítems.

Para que nos quede más fácil podemos incluir dos columnas: el costo por unidad, que se ingresaría manual, y Costo Total, donde multiplicaríamos las unidades ingresadas por el costo unitario, y para poder arrastrarla, lo «encerraríamos» en un SI

=SI(C2*D2=0;»»;C2*D2)

Ahora nos devolvemos a la pestaña Inventarios y vamos a incluir la columna COSTO PROMEDIO POR UNIDAD, donde vamos a sacar el promedio del costo de una referencia con la ayuda de la función PROMEDIO.SI

PROMEDIO.SI funciona igual a SUMAR.SI, promediando los datos de un rango que cumplan con una condición específica. En nuestro caso solo queremos promediar los costos de la referencia. La fórmula quedaría así entonces:

=PROMEDIO.SI(Entradas!B:B;B2;Entradas!D:D)

Y como siempre, la podemos encapsular en una función SI.ERROR

=SI.ERROR(PROMEDIO.SI(Entradas!B:B;B2;Entradas!D:D);»»)

Por último creamos el campo COSTO INVENTARIO donde multiplicamos las unidades del inventario por el costo promedio.

Nuestra base de inventario quedaría así:

Dar un color a los productos con bajo inventario o sin inventario

Lo último que vamos a hacer es establecer un formato condicional para que los productos con inventario 0 tengan un color diferente, alertándonos.

Podríamos solo «colorear» la columna de inventario, pero queda «más elegante» darle color a toda la fila.

Para esto vamos a seleccionar toda nuestra tabla de inventarios, clic derecho y «Formato Condicional»

En «Reglas de Formato» escogemos «Formula Personalizada» y escribimos la siguiente formula:

=$F2<=0

Donde, en mi caso, F es la columna de inventario

Por último escogemos un formato rojo, o naranja, para que nos identifique los productos sin inventario, y damos clic en «Listo»

Ahora vamos a crear otra regla igual, pero para los productos con menos de 5 unidades en inventario, con un color un poco menos de alerta (un amarillo puede ser)

Para esto, escogemos nuestra regla anterior (en el panel de formato condicional) y en la parte inferior damos clic en «Añadir otra regla», para que nos duplique esta.

La formula la cambiamos por

=$F2<=5

Y el color tambien lo cambiamos

Al final quedamos con

Búsqueda por producto

Uno de los primeros cambios que quiero hacer a mi base original es este:

Esta muy bien seleccionar el producto cuando tengo pocas referencias, pero cuando ya son muchas, puede ser muy dispendioso, sería mejor si el desplegable fuera con los nombres de los productos y no con las referencias

Vamos a hacer eso entonces:

Hay varias maneras de hacer esto, copiando y pegando las columnas, pero creo que la forma más fácil es la siguiente

  1. Nos ubicamos en la pestaña entradas
  2. Borramos el nombre «REF» O «referencia» de la primera columna, y lo cambiamos por NOMBRE
  3. Borramos el nombre «Producto» de la segunda columna y lo cambiamos por Referencia
  4. Vamos a seleccionar desde la segunda celda de la primera columna hasta la última (Con Ctrl + Shift + Abajo 2 veces)
  5. Vamos a ir a Validación de Datos
  6. Vamos a dar clic en quitar la validación de datos
  7. Vamos a copiar los nombres de la columna B
  8. Los vamos a pegar (como valores) en la columna A
  9. Volvemos a escoger la columna A, desde la fila 2
  10. Volvemos a ir a Validación de datos
  11. Vamos a dar clic sobre el cuadro que sale al lado del intervalo de datos
  12. Vamos a escoger como nuestro listado de validación la segunda columna de la base de productos (en vez de la primera)
  13. Damos clic en Aceptar

Listo, primer paso completado, ahora ya nos debería salir un desplegable con los nombres, asi:

Claramente la fórmula de la columna B esta «rota». Tenemos que cambiarla completamente.

Ya el BUSCARV no nos va a servir, porque la referencia esta a la izquierda del producto en la base de búsqueda (Producto)

Vamos a usar entonces la función indice + la función coincidir

Esto básicamente es una versión más avanzada del BUSCARV, pero hace lo mismo.

Entonces nuestra fórmula (en la celda B2) va a ser:

=SI.ERROR(INDICE(Productos!A:C;COINCIDIR(A2;Productos!B:B;0);1);»»)

Donde:

  • A2 es el nombre del producto
  • Productos!B:B es mi listado de nombres
  • 1 es la columna donde voy a buscar (la columna A de mi base de productos que es donde están las referencias)
  • Productos A:C es toda mi base de productos

Ya es solo cuestión de arrastrar la fórmula hasta el final y listo

Salidas

Ahora debemos repetir el mismo proceso para Salidas

Aunque puede ser más rápido, copiar y pegar las columnas A y B de Entradas y pegarlas en Salidas

Puedes ver este tutorial, con muchas más opciones en el curso entero de Gestión de Inventarios en mi academia de automatización de Google Sheets

Búsqueda Ordenada de Productos

Una cosa que podemos querer es que el desplegable de nombres de productos salga en orden alfabético para que la búsqueda sea más fácil y ordenada.

Para esto debemos crear una lista auxiliar de productos donde los ordenemos, y que esto sea nuestra validación de datos

Para esto nos vamos a la pestaña que ya habíamos creado de «Listas»

Y vamos en una nueva columna a incluir la siguiente formula

=SORT(Productos!B2:B1000)

Esto nos va a traer nuestro listado de nombres pero ordenado

Ahora cambiamos la validación de datos tanto en Entradas como en Salidas, para asegurarnos que traiga esta nueva lista.

Fijar filas

Cuando estamos empezando cualquier base, todo es felicidad.

Las complicaciones o retos vienen cuando hay cada vez más datos

Por ejemplo vean la base de salidas cuando ya tenemos muchos datos

Hay varios problemas cuando ya hay muchas filas.

Hoy vamos a solucionar dos de ellos

El primero es que cuando bajo a las últimas filas, se pierde el encabezado y a veces no se a lo que se refiere un número o una fecha.

Esto los solucionamos fijando o inmovilizando la fila superior

2 formas de hacerlo.

La más fácil es ubicarnos en la esquina superior izquierda de nuestra base, particularmente en su borde inferior, que es un poco más grueso y donde el cursor se convierte en una mano blanca

Y luego presionamos sobre la barra y la arrastramos hasta donde queremos, en nuestro caso la segunda fila

Nos quedaría así:

Crear nuevas entradas o salidas más rápido

Otra cosa que es aburridora con el tiempo es siempre tener que desplazarnos hasta la última fila, especialmente cuando esta dila es la 100 o la 250 o algo así.

Con Ctrl + Abajo podemos ir fácilmente a la última fila.

Pero también podemos hacerlo más sofisticado.

Podemos crear un enlace en la primera fila para que nos lleve inmediatamente a la última fila.

Esto lo haremos con la funcionalidad de enlaces a celdas, sumados de la función HIPERVINCULO

Primero vamos a situarnos en la última día y la primera columna de nuestros datos.

Después vamos a dar clic derecho y escoger Obtener enlace a la celda.

Ahora nos vamos a la primera fila en la columna después del último dato e incluir la siguiente función

=HIPERVINCULO(«https://docs.google.com/spreadsheets/d/1wzscLFEfxsWLwkXYay_xVlUfYF40xjgL0IWOY8i68VM/edit#gid=1348838985&range=A296″;»Ir a la última fila»)

Donde el link lo reemplacen pegando el enlace que acabaron de copiar de la última celda

Esto funcionaria bien pero siempre nos llevaría a la celda 296, o la que sea que es su última celda en estos momentos.

Tenemos que modificar esta celda para que siempre los lleve a la última fila actual

Para esto nos vamos a ayudar de la función CONTARA

Si ven el enlace a celda, termina con «&range=A296», entonces podríamos reemplazar el 296 con CONTARA + 1 para que siempre me ubique en la primera celda en blanco después de mi última fila

quedaría la formula asi

=HIPERVINCULO(«https://docs.google.com/spreadsheets/d/1wzscLFEfxsWLwkXYay_xVlUfYF40xjgL0IWOY8i68VM/edit#gid=1348838985&range=A»&CONTARA(A:A)+1;»Ir a la última fila»)

Esto se podría repetir para Salidas, y si lo desean parar productos.

Validación de Nuevas Salidas

Lo ultimo que quiero hacer es que el programa me avise de alguna manera cuando vaya a registrar una salida si ese producto no tiene inventario.

Para esto vamos a hacer una validación con una fórmula, específicamente con un BUSCARV.

  1. Vamos a la pestaña Salidas
  2. Escogemos la columna de unidades desde la fila 2 hasta la última (Ctrl Shift abajo dos veces
  3. Clic derecho > Validación de datos
  4. En «Criterios» escogemos «La formula personalizada es;»
  5. En fórmula ingresamos: =BUSCARV(B2;Inventario!A:F;6;0)>0
  6. Escogemos «Mostrar aviso»
  7. En «Mostrar texto de ayuda» escribimos «Este producto no tiene inventario suficiente»

Conclusión

Hemos creado una primera versión de nuestro archivo de inventarios.

Hay mucho más que le podemos hacer, pero este ya te queda funcionando y puedes ir ingresando tus datos y va a cumplir con el objetivo: Decirte cuantas unidades debería haber de cada producto de acuerdo a las entradas y salidas.

Espero lo usen y espero sus comentarios.

¿Que le has mejorado?

¿Qué te gustaría incluir?

Suscríbete para acceder al curso «Descubriendo el poder de Google Sheets» y empezar tu camino a la maestría de Sheets, Forms y Apps Script

Boletín

Nuestras últimas noticias en tu correo electrónico

Respuestas

  1. Avatar de Santiago Garcés
    Santiago Garcés

    hola Juan… primero felicitarte tu trabajo es espectacular…

    mi pregunta es como registro un numero de orden que no se pueda repetir y que el mismo me lo copie en la pestaña de inventarios para saber a que orden pertenece tal o cual ingtreso??
    ejemplo.. hoy ingresó con el numero de orden pt001… dos lechugas y 6 quesos
    mañana ingresan con el numero de orden pt002…. dos quesos y 10 piezas de pan
    es decir que en el inventario me pudiese avisar que las lechugas han ingresado con 2 órdenes diferentes… para asi de esta manera poder comparar con hojas de ingreso y tener el chance de controlar las ordenes fisicas…

    De antemano Muchas gracias por tu ayuda..

    1. Avatar de jsguzmanb
      jsguzmanb

      Podríamos agregar la columna de orden en «Ingresos»
      Ya con eso, podemos separar y hacer calculos diferenciados dependiendo de las ordenes
      Saludos!

  2. Avatar de Santiago Renzo
    Santiago Renzo

    Hola. Se podria crear este Sistema de control de Stock pero utilizando un lector de codigo de barras? Gracias

    1. Avatar de jsguzmanb
      jsguzmanb

      Estoy trabajando en ese video
      Saludos!

  3. Avatar de pablo
    pablo

    Hola, tenes alguna planilla de control de stock ya creada que pueda servirme para adaptarla a mi emprendimiento? Gracias.

    1. Avatar de jsguzmanb
      jsguzmanb

      Hola Pablo. Claro que si, en el patreon y en la academia las encuentras según los videos.
      Saludos!

  4. Avatar de javier
    javier

    Hola… de qué manera agrego diferentes locaciones a los productos (para entradas y salidas) es decir, la misma empresa tiene almacenados productos en tres o más lugares diferentes. …

    1. Avatar de jsguzmanb
      jsguzmanb

      Hola Javier

      Hay varias opciones

      1) Tener una hoja de entradas y salidas para cada bodega
      2) Tener una columna que diga bodega, para saber de que bodega sale y entra

      Saludos!

  5. Avatar de Felipe Suca
    Felipe Suca

    Muchas gracias por las enseñanzas, por tu tiempo y dedicación … estoy aprendiendo bastante y ya puedo personalizarlo a mi gusto.

    Tengo una duda… quiero hacer una CHECK LIST de los productos que vendo… por ejemplo si vendo un maquina completa quiero que salga sus componentes que la acompañan por ejemplo pedestal 1 und, guarda polvo 2und, mica protectora 1 und y eso tambien interactue con mis salidas y entradas …. es como una maquina y sus accesorios. (Los accesorios tengo repuestos) Estoy intentando con buscarv o indice pero no me cuadro.

    1. Avatar de jsguzmanb
      jsguzmanb

      Hola Felipe

      Ya has visto este video?
      https://youtu.be/gwju78H3kW4

      Te puede dar pistas

      Un gran saludo!

  6. Avatar de auswog

    Las hojas de calculos son flexibles. Pueden ser usadas para cualquier cosa desde una herramienta para rastrear tuejercicio hasta para planear una boda, como veras en este tutorial.

    1. Avatar de jsguzmanb
      jsguzmanb

      Tienes toda la razón

      Saludos!

  7. Avatar de Luis S.
    Luis S.

    En la pestaña Inventario, a partir de esta fórmula:
    +SI(SUMAR.SI(Entradas!B:B;A2;Entradas!C:C)=0;»»;SUMAR.SI(Entradas!B:B;A2;Entradas!C:C))

    1. Cómo puedo hacer que únicamente sume los valores positivos?
    2. Cómo puedo hacer que me sume las entradas por categoría? Es decir, tengo categorías de entradas, por producción y por devolución

  8. Avatar de Beatriz Vianey Rodriguez
    Beatriz Vianey Rodriguez

    Buenas tardes, primero que nada ¡Excelente video felicidades!

    Tengo una pregunta, ojala tengas tiempo para contestar.

    Yo tengo un inventario en el que en una pestaña tengo agregado un control de equipos móviles, en el tengo las siguientes columnas; marca, modelo, nombre de responsable, estatus. En el estatus por ejemplo tiene disponible y no disponible.

    Me gustaría saber la manera de hacer una fórmula en la que yo en otra pestaña pueda sumar cuantas tablet disponibles le quedan a cada responsable.

    Te agradecería mucho que me ayudes con esta duda !

    ¡Saludos!

    1. Avatar de jsguzmanb
      jsguzmanb

      Hola Beatriz

      Esto se hace con una formula llamada SUMAR.SI.CONJUNTO y es muy fácil!

      En este artículo te lo explico

      https://juansguzman.com/todas-las-formas-de-sumar-en-google-sheets/

      Me cuentas si te quedan dudas

      Saludos!

  9. Avatar de Cecilia Santomassimo
    Cecilia Santomassimo

    Hola buenas tardes! la planilla esta buenisima y la vengo usando hace un mes. Pero me he encontrado con un error que no he logrado solucionar.
    Ya cargué varias entradas de productos, pero ahora quiero hacer una segunda carga de productos ya que me entró un nuevo pedido y cuando selecciono la referencia NO me trae el nombre del producto. Ya he chequeado a las formulas, pero esto me sucede cuando hago una segunda entrada de un producto con entradas anteriores.

    1. Avatar de jsguzmanb
      jsguzmanb

      Hola Cecilia

      Hagamos un ejercicio:

      PArate en la celda B2 (o donde este el nombre del producto) y pegame esa formula

      Ahora párate en la celda B20, mejor dicha en la misma columna pero muchas filas abajo y copia la formula

      Quiero ver si es algo al arrastrar la formula

      Un gran saludo!

      1. Avatar de Cecilia Santomassimo
        Cecilia Santomassimo

        El problema era que le faltaban los $$ a la formula. Gracias.

        1. Avatar de Eduardo
          Eduardo

          Hola Cecilia…. tengo el mismo problema, me serviría mucho tu ayuda.
          Dónde colocaste «$$» ?

          Saludos!

          1. Avatar de jsguzmanb
            jsguzmanb

            Hola Eduardo

            Los signos peso van delante de las columnas, así

            =SI.ERROR(BUSCARV(A2;Productos!$A:$B;2;0);»»)

            Saludos!

  10. Avatar de Dennis
    Dennis

    Hola Juan, primero que nada darte las gracias y felicitarte, me gustó el video, muy bien explicado.
    Segundo, tengo una pregunta, ¿Qué ocurre si quiero agregar el costo del inventario?
    Que me diga cuanto tengo invertido en inventario de cada producto.

    Por ejemplo, digamos que los productos que compro cambian de precio constantemente, ¿es posible que google sheet guarde un registro o una base de datos de los productos que entran y su precio así ? Lo mismo para las salidas, ¿Es posible que registre las salidas y el precio correspondiente de cada una? y al final ¿se puede hacer un valor total del inventario restante de ese producto?

    1. Avatar de jsguzmanb
      jsguzmanb

      Hola Dennis

      Mil gracias!

      El costo es un tema complicado porque hay muchas maneras de hacerlo

      Te invito a ver la serie completa de inventarios donde te voy mostrando distintas maneras de incluir el costo.

      https://www.youtube.com/playlist?list=PLvrIQ0wr2BTL4e8KpPodilzRgob5zcteh

      Seguro hay alguna que te aplique mejor a ti.

      Me cuentas si te sirve.

      Saludos!

Deja una respuesta

Tu dirección de correo electrónico no será publicada. Los campos obligatorios están marcados con *

Este sitio usa Akismet para reducir el spam. Aprende cómo se procesan los datos de tus comentarios.

Pin It on Pinterest

Share This